Tue 10 Jan 23 @ 5:29 pm

Autoplay next from Songlist
At the end of a song the next song from the songlist will load and play.
When you select a other song in the Songlist, this one will play at next.
After the last Song of the Songlist the script and the music stoped.
https://www.youtube.com/watch?v=XVHBYr89i0E

(repeat_start 'loadnextplay' ? blink : nothing ) &
( action_deck 1 ? deck 2 repeat_stop 'loadnextplay' & deck 3 repeat_stop 'loadnextplay' & deck 4 repeat_stop 'loadnextplay' ) &
( action_deck 2 ? deck 1 repeat_stop 'loadnextplay' & deck 3 repeat_stop 'loadnextplay' & deck 4 repeat_stop 'loadnextplay' ) &
( action_deck 3 ? deck 1 repeat_stop 'loadnextplay' & deck 2 repeat_stop 'loadnextplay' & deck 4 repeat_stop 'loadnextplay' ) &
( action_deck 4 ? deck 1 repeat_stop 'loadnextplay' & deck 2 repeat_stop 'loadnextplay' & deck 3 repeat_stop 'loadnextplay' ) &
( repeat_start 'loadnextplay' ? repeat_stop 'loadnextplay' : repeat_start 'loadnextplay' 100ms &
( songpos_remain 150ms ? browser_scroll 'bottom' ? param_equal `param_add "get_loaded_song 'title'" "get_loaded_song 'artist'"` `param_add "get_browsed_song 'title'" "get_browsed_song 'artist'"` ? repeat_stop 'loadnextplay' : nothing : nothing ) &
( songpos_remain 150ms ? param_equal `param_add "get_loaded_song 'title'" "get_loaded_song 'artist'"` `param_add "get_browsed_song 'title'" "get_browsed_song 'artist'"` ? pause & browser_window 'songs' & browser_scroll +1 & load & browser_scroll 0 & play : pause & browser_window 'songs' & load & browser_scroll 0 & play : nothing : nothing ) )

GAIN - Talkover
for faster or slower slide, change "gain +3% / -3% values"
for the down position change "12% gain ? gain 10%"

down ? ( repeat_stop gainup & param_equal `get_var loadedtemp` `get_loaded_song title` ? nothing :
 set loadedtemp `get_loaded_song title` & set gaintemp `gain` & set gaintemp2 `param_add "get_text '-2' & param_cast percentage" "get_var gaintemp & param_cast percantage"` ) &
 ( repeat_start_instant gaindown 30ms & param_smaller 12% gain ? gain 10% : gain -3% ) : 
 ( repeat_stop gaindown ) & 
 ( repeat_start_instant gainup 30ms & param_bigger 'get_var gaintemp2' gain ? repeat_stop gainup & get_var gaintemp & param_cast 'percentage' & gain : gain +3% )

Sampler - Talkover
set Sampler Output to Master, activate the script, play sampler and the Deck Volume of the Master Deck goes to 50% (0.5), after the end of the Sampler the volume goes back to 100%

deck master repeat_start 'sampvol' ? on & deck master repeat_stop 'sampvol' : deck master repeat_start 'sampvol' 50ms & 
( deck master param_bigger 0.99 `deck master volume` ? sampler_used ? deck master volume 0.51 : nothing ) & 
( deck master volume 0.51 ?  sampler_used ? nothing : deck master volume 1 )

Video Text Ovelay - Countdown with Text at the end.

deck master repeat_start TEXTBLINK ? deck master video_fx text on & deck master repeat_stop TEXTBLINK :
 deck master repeat_start NYECount ? on & deck master video_fx text off & deck master repeat_stop NYECount :
 off & deck master video_fx text on & deck master repeat_start NYECount 50ms &
 param_smaller `countdown '2023/01/01 00:00:00'` 10 ?
 countdown '2023/01/01 00:00:00' %full & param_cast & effect_string 'text' 2 :
 param_equal `countdown '2023/01/01 00:00:00' %SS` "00" !?
 effect_string text 3 bigNumber & countdown '2023/01/01 00:00:00' %SS & param_cast & effect_string 'text' 2 :
 effect_string text 3 messageBox & effect_string text 2 "Happy NEW YEAR" & deck master repeat_stop NYECount &
 effect_string audioonlyvisualisation 1 'Fireworks' & effect_button audioonlyvisualisation 3 off &
 deck master set 'textblinkvar' 0 & deck master repeat_start TEXTBLINK 500ms & deck master var_smaller 'textblinkvar' 999 ?
 deck master set 'textblinkvar' +1 &  deck master video_fx text off & wait 250ms & deck master video_fx text on & wait 250ms :
 deck master  repeat_stop TEXTBLINK

Video Text Ovelay - Current Time

deck master repeat_start TIME ? on & effect_active text off & repeat_stop TIME :
 off & effect_active text on & repeat_start TIME 50ms &
 effect_string text 3 bigNumber & get_clock & param_cast & effect_string 'text' 2

Rate the loaded Track ★★★★★ - Action

loaded_song 'rating' 0 ? loaded_song 'rating' 1 :
 loaded_song 'rating' 1 ? loaded_song 'rating' 2 :
 loaded_song 'rating' 2 ? loaded_song 'rating' 3 :
 loaded_song 'rating' 3 ? loaded_song 'rating' 4 :
 loaded_song 'rating' 4 ? loaded_song 'rating' 5 :
 loaded_song 'rating' 5 ? loaded_song 'rating' 0

Rate the loaded Track ★★★★★ - Button Name

`loaded ? loaded_song 'rating' 0 ? get_text 'no rating' : get_loaded_song 'rating' : get_text 'not load'`

Manually input Dialog for set Pitch to a specific BPM Value

off & set set_bpm `get_bpm` & set_var_dialog set_bpm BPM &
 repeat_start 'bpm_change' 250ms 240 & 
 param_equal '`get_var set_bpm`' '`get_bpm`' ? nothing :
 get_var set_bpm & param_cast 'beats' & pitch & repeat_stop 'bpm_change'

Lock Cues of all Tracks in the Browser

setting saveUnplayedToSidelist ? off & setting saveUnplayedToSidelist &
 repeat_start 'cuelock' ? on & repeat_stop 'cuelock' : off &
 repeat_start 'cuelock' 150ms & browser_scroll 'bottom' ?
 repeat_stop 'cuelock' & load_next & lock_cues on & browser_scroll 'top' & unload & setting saveUnplayedToSidelist :
 browser_scroll +1 & load & lock_cues on :repeat_start 'cuelock' ? on & repeat_stop 'cuelock' : off &
 repeat_start 'cuelock' 150ms & browser_scroll 'bottom' ?
 repeat_stop 'cuelock' & load_next & lock_cues on & browser_scroll 'top' & unload :
 browser_scroll +1 & load & lock_cues on

Unlock Cues of all Tracks in the Browser

setting saveUnplayedToSidelist ? off & setting saveUnplayedToSidelist &
 repeat_start 'cuelock' ? on & repeat_stop 'cuelock' : off &
 repeat_start 'cuelock' 150ms & browser_scroll 'bottom' ?
 repeat_stop 'cuelock' & load_next & lock_cues off & browser_scroll 'top' & unload & setting saveUnplayedToSidelist :
 browser_scroll +1 & load & lock_cues off :repeat_start 'cuelock' ? on & repeat_stop 'cuelock' : off &
 repeat_start 'cuelock' 150ms & browser_scroll 'bottom' ?
 repeat_stop 'cuelock' & load_next & lock_cues off & browser_scroll 'top' & unload :
 browser_scroll +1 & load & lock_cues off

Video Audio Only Source - Load a specifice Folder for the Slideshow Plugin

param_equal `get_effect_string audioonlyvisualisation 1` 'FULLPATH' ? on : off & video_source_select slideshow & effect_string audioonlyvisualisation 1 'FULLPATH'

Video Overlay - Load a specifice Folder for the Slideshow Plugin

param_equal `deck master effect_string slideshow 1` 'FULLPATH' ? on : off & deck master effect_string slideshow 1 'FULLPATH'

Collapse folder tree

off & repeat_start 'collapse' ? repeat_stop 'collapse' :
 browser_window 'folders' & browser_scroll 'top' & repeat_start 'collapse' 30ms &
 browser_open_folder off & browser_scroll +1 &
 browser_scroll 'bottom' ?
 repeat_stop 'collapse' & browser_scroll 'top' :
 nothing